int numStars = 100;
int twinklePerFrame = 5;

color sky = color(25, 25, 112);

float x[] = new float[numStars];
float y[] = new float[numStars];
int alpha[] = new int[numStars];

void setup() {
  size(600, 400);
  // pick initial star locations
  for (int j=0; j<numStars; j++) {
    randomizeStar(j);
  }
}

void randomizeStar(int j) {
  x[j] = random(width);
  y[j] = random(220);    // above horizon
  alpha[j] = int(random(55, 255));
}

void draw() {
  background(sky);

  // pick random star and change its transparency
  for (int k=0; k < twinklePerFrame; k++) {
    int s = int(random(numStars));    // pick random star index
    alpha[s] = int(random(55, 255));
  }

  // render stars here...
  strokeWeight(1);
  for (int j=0; j<numStars; j++) {
    stroke(255, alpha[j]);
    point(x[j], y[j]);
  }

  // moon
  noStroke();
  fill(180, 200, 220);
  ellipse(500, 100, 60, 60);
  fill(sky);
  ellipse(520, 100, 60, 60); // mask to leave cresent shape


  // grass
  fill(0, 255, 0);
  stroke(0, 255, 0);
  strokeWeight(1);
  rect(0, 240, 600, 160);

  // tree
  stroke(0);
  fill(0, 100, 0);
  triangle(100, 160, 60, 280, 140, 280);

  // house facade
  fill(255);
  rect(220, 200, 120, 120);

  // house roof
  fill(127);
  quad(210, 210, 350, 210, 340, 170, 220, 170);


  // chimney
  stroke(255, 0, 0);
  fill(255, 0, 0);
  rect(296, 144, 30, 56);

  // window
  fill(0);
  strokeWeight(2);
  rect(246, 220, 30, 40);
}