String prose = "Episode IV\nA NEW HOPE\n\nIt is a period of civil war. Rebel spaceships, striking from a hidden base, have won their first victory against the evil Galactic Empire.\n\nDuring the battle, Rebel spies managed to steal secret plans to the Empire's ultimate weapon, the DEATH STAR, an armored space station with enough power to destroy an entire planet.\n\nPursued by the Empire\'s sinister agents, Princess Leia races home aboard her starship, custodian of the stolen plans that can save her people and restore freedom to the galaxy....";

float offset = -100;  // wait a bit before coming on screen

PVector stars[] = new PVector[1000];

void setup() {
  size(800, 800, P3D);
  textSize(60);
  textAlign(TOP, LEFT);
  strokeWeight(2);
  stroke(255);  // white stars
  fill(255, 255, 0); // yellow text
  for (int j = 0; j < stars.length; j++) {
    stars[j] = new PVector(random(width), random(height));
  }
}

void draw() {
  background(0);

  for (int j=0; j < stars.length; j++) {
    point(stars[j].x, stars[j].y);
  }

  offset += 2;

  translate(0, height);   // hinge on bottom edge of the screen
  rotateX(QUARTER_PI);
  translate(0, -offset);
  text(prose, 0, 0, width, 10*height);
}