/*
 * Mandala implementation from Greenberg, Xu, Kumar text.
 * (with slight change by Michael Goldwasser)
 */

void setup() {
  size(600, 600);
  background(0);
  noStroke();
  translate(width/2, height/2);
  
  // parameters to customize the mandala
  int pointCount = 8;
  int steps = 300;
  float outerRadius = width * 0.5;
  float innerRadiusFactor = 0.7;
  float totalRotation = 55.0;
  
  // values derived from above parameters
  float innerRadius = outerRadius * innerRadiusFactor;
  float outerRadiusRatio = outerRadius/steps;
  float innerRadiusRatio = innerRadius/steps;
  float shadeRatio = 255.0/steps;
  float rotationRatio = totalRotation/steps;
  
  for (int i=0; i<steps; i++) {
    fill(shadeRatio*i);
    pushMatrix();
    rotate(rotationRatio*i*PI/180);
    star(pointCount, outerRadius-outerRadiusRatio*i, innerRadius-innerRadiusRatio*i);
    popMatrix();
  }
}


void draw() {
}


void star(int pointCount, float innerRadius, float outerRadius) {
  float theta = 0.0;
  // point count is 1/2 of total vertex count
  int vertCount = pointCount*2;
  float thetaRot = TWO_PI/vertCount;
  float tempRadius = 0.0;
  float x = 0.0, y = 0.0;

  beginShape();
  for (int i=0; i<pointCount; i++) {
    for (int j=0; j<2; j++) {
      tempRadius = innerRadius;

      // true if j is even
      if (j%2==0) {
        tempRadius = outerRadius;
      }

      x = cos(theta)*tempRadius;
      y = sin(theta)*tempRadius;
      vertex(x, y);
      theta += thetaRot;
    }
  }
  endShape(CLOSE);
}