/*------------------------------------------------------------
 Displaying live YTD stock prices using Yahoo as data source.
 
 Author: Michael Goldwasser
 
 This project is derivative of an original example acompanying
 the book:
 
 Processing: Creative Coding and Generative Art in Processing 2
 By Ira Greenberg, Dianna Xu, and Deepak Kumar
 Friends of Ed (An APress Company), 2013
 ISBN-13 978-1430244646
 Please refer to the associated README for a full disclaimer.
 
 Copyright (c) 2013, Friends of Ed (An Apress Company)
 All rights reserved.
 ------------------------------------------------------------*/

String symbol = "GOOG";  // initial choice

class Entry {
  float price;  // we'll use adjusted close
  int volume;
  int month;
  int date;
  int year;
};

Entry[] quotes;
float minPrice, maxPrice;
float increment = 10;       // how can this be better tailored?

float X1, Y1, X2, Y2;

PFont legendFont = createFont("SansSerif", 20);

void setup() {
  // drawing setup
  size(800, 600);

  X1 = 50; 
  Y1 = 50;
  X2 = width - 50; 
  Y2 = height - 50;
  textFont(legendFont);

  refresh();
} // setup()

// used to (re)load stop information and to render the graph
void refresh() {
  symbol = symbol.toUpperCase();
  loadData();
  drawGraph();
  symbol = "";  // reset; can use keyboard to enter a new symbol
}

void loadData() {
  // Load the historical data file...
  String url = "http://ichart.yahoo.com/table.csv?s=";
  url += symbol;
  url += "&a=0&b=1&c=1900";  // start date
  url += "&d=" + (month()-1);
  url += "&e=" + day();
  url += "&f=" + year();
  url += "&ignore=.csv";
  String[] lines = loadStrings(url);
  if (lines == null) {
    println("Unable to load information about symbol: " + symbol);
    quotes = null;
  } else {
    lines = reverse(lines);  // Yahoo returns newest first

    // How long is the dataset
    quotes = new Entry[lines.length-1]; // subtract one to ignore header line

    // Parse the needed data
    for (int i=0; i<quotes.length; i++) {
      // Frst split each line using commas as separator
      String[] pieces = split(lines[i], ",");

      // get the closing price of stock, and month
      quotes[i] = new Entry();
      quotes[i].price = float(pieces[6]);
      quotes[i].volume = int(pieces[5]);
      String date = pieces[0];
      String[] temp = split(date, '-');
      quotes[i].year = int(temp[0]);
      quotes[i].month = int(temp[1]);
      quotes[i].date = int(temp[2]);
    }
    println("Data Loaded: "+quotes.length+" entries.");

    // determine min and max stock price for the year
    minPrice = maxPrice = quotes[0].price;
    for (int k=1; k < quotes.length; k++) {
      minPrice = min(minPrice, quotes[k].price);
      maxPrice = max(maxPrice, quotes[k].price);
    }
    println("Min: "+minPrice);
    println("Max: "+maxPrice);
  }
}

void drawGraph() {
  background(0);

  // draw plot bounding box
  rectMode(CORNERS);
  noStroke();
  fill(255);
  rect(X1, Y1, X2, Y2);

  // draw graph of stock prices
  if (quotes != null) {
    stroke(0);
    strokeWeight(1);
    beginShape();
    for (int i=0; i < quotes.length; i++) {
      float x = map(i, 0, quotes.length-1, X1, X2);
      float y = map(quotes[i].price, minPrice, maxPrice, Y2, Y1);
      vertex(x, y);
    }
    endShape();


    // draw legend

    // Load the full name of the stock for caption
    String url = "http://finance.yahoo.com/d/quotes.csv?f=n&s=";
    url += symbol;
    String full = loadStrings(url)[0];
    full = full.substring(1, full.length()-1);  // remove quotation marks
    String caption = "(" + symbol + ") " + full;

    // title
    fill(255);
    textSize(18);
    textAlign(LEFT);
    text(caption, X1, Y1 - 10);
    textSize(10);
    textAlign(RIGHT, BOTTOM);
    text("Source: Yahoo! Finance (finance.yahoo.com)", width-10, height-10);

    // axis labels
    drawXLabels();
    drawYLabels();
  }
}

void drawYLabels () {
  fill(255);
  textSize(10);
  textAlign(RIGHT);
  for (float i=minPrice; i <= maxPrice; i += increment) {
    float y = map(i, minPrice, maxPrice, Y2, Y1);
    text(nf(i, 0, 1), X1-10, y);
    stroke(255);
    line(X1-5, y, X1, y);
    stroke(0);
    line(X1, y, X2, y);
  }
  textSize(18);
  text("$", X1-40, height/2);
} // drawYLabels()

void drawXLabels() {
  fill(255);
  stroke(0);
  textSize(10);
  textAlign(CENTER);

  boolean multiyear = (quotes[0].year != quotes[quotes.length-1].year);

  String prev = "";
  for (int i=0; i<quotes.length; i++) {
    String label = getLabel(quotes[i], multiyear);
    if (!label.equals(prev)) {
      prev = label;
      float x = map(i, 0, quotes.length, X1, X2);
      text(label, x, Y2+10);
      strokeWeight(0.3);
      line(x, Y2, x, Y1);
    }
  }
  textSize(18);
  textAlign(CENTER, TOP);
  text("Trading Date", width/2, Y2+10);
} // drawXLabels()

String getLabel(Entry e, boolean multiyear) {
  if (multiyear) {
    return "" + e.year;
  } else {
    return "" + e.month;
  }
}

// this is required to allow user interactions
void draw() {
}

void mouseClicked() {
  save("Chart.jpg");
}

void keyPressed() {
  if (key == ENTER || key == RETURN) {
    refresh();    // load and graphd data for current symbol
  } else if ((key >= 'a' && key <= 'z') || (key >= 'A' && key <= 'Z')) {
    symbol += key;
  }
}